AutoHotkey como alternativa a Logitech Options – Más control del ratón y el teclado

/ Programas

AutoHotkey Script Windows Windows 10 Windows 11

Desde hace varios años utilizo en todos mis ordenadores y portátiles una herramienta que facilita enormemente mi trabajo diario: AutoHotkey. La descubrí por casualidad mientras buscaba una alternativa a Logitech Options, el software oficial para personalizar las funciones de los botones de mis Logitech MX Master 3 y MX Master 3S (*).

Aunque Logitech Options ofrece muchas funciones, el programa me resultaba demasiado pesado. Tenía que instalarlo en todos los dispositivos únicamente para utilizar los botones del ratón como de costumbre. También causaba problemas en algunas aplicaciones, como DaVinci Resolve: los atajos no funcionaban correctamente hasta cerrar por completo el software de Logitech. Por eso busqué una solución más flexible y encontré AutoHotkey.

Qué es AutoHotkey

AutoHotkey (AHK) es un programa gratuito y de código abierto para Windows que permite crear comandos propios para el teclado y el ratón. Básicamente, es un lenguaje de scripts que automatiza las entradas de Windows. Permite:

  • crear atajos para el teclado y el ratón
  • ejecutar acciones complejas con una sola pulsación
  • completar textos automáticamente
  • iniciar programas o colocar ventanas
  • integrar controles multimedia de volumen o reproducción

Su principal ventaja es que no estás limitado a un ratón o teclado concreto. Mientras Logitech Options solo funciona con dispositivos Logitech, AutoHotkey es compatible con prácticamente cualquier ratón, teclado e incluso mando de juego.

Por qué utilizo AutoHotkey

Utilizo AutoHotkey tanto en el ámbito privado como profesional, sobre todo para trabajar de forma más productiva. He configurado el ratón y el teclado para ejecutar muchas funciones con mayor rapidez sin mantener software adicional en segundo plano.

Por ejemplo, controlo el volumen directamente con los botones laterales del ratón o cambio de pestaña en Firefox y el Explorador de Windows combinando varios botones.
En el teclado, un sencillo atajo abre Windows Terminal normalmente o como administrador. También puedo regular el volumen en pasos del 10 % con el teclado numérico.

Guardo el script en la carpeta de inicio automático de Windows para que se ejecute al arrancar el PC. Puedes abrir rápidamente esa carpeta mediante shell:startup.

Mis scripts de AutoHotkey más importantes

Puedes descargar el script completo aquí, copiarlo desde Pastebin o utilizar este enlace con publicidad.

autohotkey-01-mouse-buttons

autohotkey-01-mouse-buttons

autohotkey-02-keyboard-buttons

autohotkey-02-keyboard-buttons

1. Abrir Windows Terminal

Abro Windows Terminal con CTRL+ALT+T y lo inicio directamente con permisos de administrador mediante CTRL+ALT+MAYÚS+T:

; Windows Terminal
; STRG+ALT
^!T::
	WinActivate Program Manager ; desktop
	RUN wt.exe
return

; Windows Terminal Elevated/Admin User
; STRG+ALT+SHIFT
^!+T::
	WinActivate Program Manager ; desktop
	RUN *RunAs wt.exe
return

2. Controlar el volumen con el ratón

Los botones laterales de mi ratón Logitech están configurados para controlar el volumen:

; Mouse Forward - Volume Up
XButton2::
    Send {Volume_Up}
; SoundSet,+5 ;Volume +5
; while(GetKeyState("XButton2","P")){
;     Send {Volume_Up}
;     Sleep, 100
; }
return

; Mouse Back - Volume Down
XButton1::
	Send {Volume_Down}
	; SoundSet,-5 ;Volume -5
return

3. Cambiar de pestaña

Manteniendo pulsado el botón lateral y haciendo clic con el botón izquierdo o derecho puedo recorrer las pestañas hacia delante o hacia atrás:

; Mouse Thumb Forward - Tab Right
XButton2 & LButton::
    while(GetKeyState("XButton2","P") && GetKeyState("LButton","P")){
        Send ^+{Tab}
        Sleep, 400
    }
return

; Mouse Thumb Forward - Tab Left
XButton2 & RButton::
    while(GetKeyState("XButton2","P") && GetKeyState("RButton","P")){
        Send ^{Tab}
        Sleep, 400
    }
return

; Mouse Thumb Forward - Reload
XButton2 & MButton::
	Send ^R
return

; Mouse Thumb Back - Close Tab
XButton1 & MButton::
    ;Send ^W
	Send ^{F4}
return

4. Mover ventanas y escritorios virtuales

La rueda y los botones laterales permiten mover ventanas o cambiar de escritorio:

; Mouse Thumb Back - Virtual Desktop Left
XButton1 & LButton::
    Send #^{LEFT}
return

; Mouse Thumb Back - Virtual Desktop Right
XButton1 & RButton::
    Send #^{Right}
return

; Wheel Up - Move Window Left
XButton2 & WheelUp::
	Send #{LEFT}
return
    
; Wheel Down - Move Window Right
XButton2 & WheelDown::
	Send #{RIGHT}
return

; Wheel Up - Zoom in
XButton1 & WheelUp::
	Send ^{WheelUp}
return
    
; Wheel Down - Zoom out
XButton1 & WheelDown::
	Send ^{WheelDown}
return

5. Controlar el volumen con el teclado numérico

Con WIN+CTRL+TECLADO NUMÉRICO puedo ajustar el volumen en pasos de 10:

#^Numpad0::
	SoundSet,0 ; set Volume to 0
	Send {Volume_Mute} ; Volume mute
        ; SoundSet,0 ; Volume mute
return

#^Numpad1::
	Send {Volume_Up} ; damit das Volume overlay angezeigt wird
	SoundSet,10 ; set Volume to 10
return

#^Numpad2::
	Send {Volume_Up} ; damit das Volume overlay angezeigt wird
	SoundSet,20 ; set Volume to 20
return

#^Numpad3::
	Send {Volume_Up} ; damit das Volume overlay angezeigt wird
	SoundSet,30 ; set Volume to 30
return

#^Numpad4::
	Send {Volume_Up} ; damit das Volume overlay angezeigt wird
	SoundSet,40 ; set Volume to 30
return

#^Numpad5::
	Send {Volume_Up} ; damit das Volume overlay angezeigt wird
	SoundSet,50 ; set Volume to 30
return

#^Numpad6::
	Send {Volume_Up} ; damit das Volume overlay angezeigt wird
	SoundSet,60 ; set Volume to 30
return

#^Numpad7::
	Send {Volume_Up} ; damit das Volume overlay angezeigt wird
	SoundSet,70 ; set Volume to 30
return

#^Numpad8::
	Send {Volume_Up} ; damit das Volume overlay angezeigt wird
	SoundSet,80 ; set Volume to 30
return

#^Numpad9::
	Send {Volume_Up} ; damit das Volume overlay angezeigt wird
	SoundSet,90 ; set Volume to 30
return

Explicación de los comandos de AutoHotkey utilizados

Para entender mejor cómo funcionan los scripts, conviene repasar brevemente los principales comandos de AutoHotkey que utilizo. Muchos son fáciles de comprender cuando se conoce su función:

  • #SingleInstance Force
    Este comando impide que se abra una segunda instancia al iniciar un script. Si el script ya se está ejecutando, se reinicia automáticamente, lo que resulta práctico al probar o modificar el código.
  • #NoEnv
    Evita que se importen variables de entorno antiguas de Windows. Esto hace que los scripts sean más estables y rápidos, especialmente en sistemas modernos.
  • ^, !, +, #
    Estos símbolos representan teclas modificadoras:
    • ^ = Ctrl (Control)
    • ! = Alt
    • + = Shift
    • # = Tecla Windows
      Por ejemplo, ^!T representa la combinación Ctrl + Alt + T.
  • Send
    Es el comando más importante de AutoHotkey. Simula pulsaciones de teclado o clics del ratón. Ejemplo:
    Send {Volume_Up} aumenta el volumen como si pulsaras la tecla correspondiente del teclado.
  • Run
    Inicia un programa o abre un archivo. Por ejemplo, Run wt.exe abre Windows Terminal.
    Combinado con *RunAs, permite iniciar el programa con permisos de administrador.
  • GetKeyState()
    Comprueba si se mantiene pulsada una tecla determinada. Así pueden crearse combinaciones, por ejemplo mantener dos botones del ratón pulsados simultáneamente para cambiar de pestaña.
  • Sleep
    Añade una breve pausa entre comandos, normalmente en milisegundos. Por ejemplo, Sleep, 400 espera 0,4 segundos antes de ejecutar el siguiente comando. Esto evita que los comandos se ejecuten demasiado rápido.
  • SoundSet
    Controla directamente el volumen del sistema. Puedes establecer valores fijos, como SoundSet,50 para un volumen del 50 %, o aumentarlo y reducirlo gradualmente.
  • WinActivate
    Activa una ventana determinada antes de ejecutar un comando. Resulta útil para asegurarse de que el script interactúa con el programa correcto.

Estos comandos son la base de casi todos los scripts de AutoHotkey. Con un poco de práctica permiten crear automatizaciones complejas, desde sencillos atajos hasta flujos de trabajo completos para Windows.

Ventajas de AutoHotkey

  • Funciona en cualquier PC con Windows, independientemente del fabricante del ratón o el teclado
  • No requiere iniciar sesión en una cuenta ni en la nube
  • Los scripts pueden exportarse y utilizarse fácilmente en otros dispositivos
  • Sin procesos en segundo plano ni telemetría
  • Carga de CPU y consumo de memoria muy bajos
  • Ideal para usuarios avanzados, desarrolladores y jugadores

Consejos útiles para empezar

  • Probar los scripts: abre el archivo .ahk con un doble clic y comprueba que todo funcione como deseas.
  • Configurar el inicio automático: coloca el script en shell:startup para activarlo cada vez que se inicie Windows.
  • Ayuda de sintaxis: AutoHotkey dispone de una documentación excelente para consultar cómo implementar tus propias ideas.
  • Consejo de seguridad: descarga scripts únicamente de fuentes fiables, ya que AHK puede automatizar pulsaciones de teclado.

Preguntas frecuentes sobre AutoHotkey

1. ¿Es seguro AutoHotkey?
Sí, AutoHotkey es seguro y cuenta con el mantenimiento de una gran comunidad. No obstante, utiliza únicamente scripts de fuentes fiables, ya que pueden simular pulsaciones de teclado.

2. ¿AutoHotkey solo funciona con determinados ratones o teclados?
No, AutoHotkey funciona con prácticamente cualquier ratón y teclado, independientemente del fabricante. Esta es una de sus mayores ventajas frente a herramientas como Logitech Options o Razer Synapse.

3. ¿Puedo utilizar AutoHotkey sin conocimientos de programación?
Sí. Muchos scripts solo tienen unas pocas líneas de código. Para crear atajos sencillos bastan conocimientos básicos, y la documentación oficial explica todos los comandos con claridad.

4. ¿AutoHotkey también funciona en Windows 11?
Sí, AutoHotkey funciona sin problemas en Windows 10 y Windows 11. Es totalmente compatible y se actualiza con regularidad.

5. ¿Cómo puedo ejecutar automáticamente mi script al iniciar Windows?
Copia el archivo .ahk en la carpeta de inicio automático (shell:startup). El script se iniciará automáticamente después de reiniciar.

6. ¿Puede AutoHotkey sustituir completamente a Logitech Options?
En la mayoría de los casos, sí. La asignación de botones del ratón, los atajos, el control de ventanas y los controles multimedia pueden reproducirse fácilmente en distintos dispositivos. Solo las funciones específicas del hardware, como el estado de la batería o Logitech Flow, siguen siendo exclusivas de Logitech.

7. ¿Cuál es la diferencia entre Send y SendInput?
Ambos comandos envían pulsaciones de teclado, pero SendInput funciona de forma más rápida y fiable en aplicaciones modernas. Send suele ser suficiente para automatizaciones sencillas.

8. ¿Cómo puedo detener o reiniciar los scripts?
Un script de AutoHotkey en ejecución aparece en el área de notificación. Haz clic con el botón derecho para seleccionar Pause, Reload o Exit.

9. ¿Puedo ejecutar varios scripts al mismo tiempo?
Sí, puedes ejecutar tantos scripts como quieras en paralelo. Si combinas muchas funciones, normalmente resulta más claro agruparlo todo en un único script.

10. ¿Dónde puedo encontrar más ideas y ejemplos?
El sitio web oficial de AutoHotkey contiene numerosos ejemplos y una comunidad activa en la que los usuarios comparten sus scripts. Allí encontrarás inspiración para casi cualquier uso, desde macros para juegos hasta automatizaciones de oficina.

(*) Enlaces de afiliado

Este artículo ha sido traducido con ayuda de IA.

Durchschnittliche Bewertung 0 / 5. Bewertungen: 0

Leave a Comment

Tu dirección de correo electrónico no será publicada. Los campos obligatorios están marcados con *

Related Posts

Scroll to Top